传奇免费版本仿梦幻西游的临时强化符脚本
本脚本有些变量需要自己更改，请查看与自己服的变量是否有冲突的，有冲突的请自行修改！U99 变量为 活力值 变量，其他变量在文本内有相应说明！
需要在QM下做一个定时器
具体条件请自行查看与修改！
DB数据库内需要加2个物品 空白强化符，强化符StdMode位置选择宝石代号63 其他都0，LOOKS外观自己选择 其他值全部0
在QManage.txt文本下加入这段话
[@Login]
#IF
CHECKLEVELEX > 0
#ACT
#CALL [\游戏登陆\定时器.txt] @定时
在QuestDiary文件夹下新建一个文件夹 重命为 游戏登录 然后在此文件夹内新建TXT文本 命名为 定时器.txt打开文本后
[@定时]
{
#if
checklevelex > 0
#ACT
SetOnTimer 1 3600
}
接下来我们回到QManage.txt下这么写
[@OnTimer1]
#if
CHECKLEVELEX > 0
#act
inc U99 1
;=====npc脚本正文
[@main]
#if
#act
#say
上古时期，遗留下的神符，引自身神力入符，后将符附于装备强化!\
少侠我这里有空白强化符出售，当然需要花上一点点小钱拉!\
当然你也可以在我这里对空白符进行神力灌输!\
灌输神力说明：请确保背包内有[空白强化符]，每次神力画符消耗1点活力!\
活力获得说明：每天在线1小时自动获得1点神力!\
强化自身说明：将已灌输神力的[强化符]佩带至宝石位置!然后进行人物属性强化!\
购买<空白强化符/@空白符><灌输神力/@灌输神力><增强自身属性/@强化自身>\
[@空白符]
#if
;检查金币，具体需要条件费用自己更换
checkgold 5000
#act
;收取金币，给予空白符
take 金币 5000
give 空白强化符 1
sendmsg 6 恭喜少侠获得一张【空白强化符】，少侠需要灌输神力，请找我!
[@灌输神力]
#if
;此变量为检测人物活力值是否大于0，U99变量需要自己在QM登录脚本下加一个QF定时器触发脚本，每1小时增加1点 具体加法看说明书
LARGE U99 0
;检测人物背包内是否有空白符
CHECKITEM 空白强化符
;#ACT表示判断
#act
;DEC U99 1表示活力值减1
DEC U99 1
TAKE 空白强化符 1
;将人物攻击赋予N0变量除以100后乘以30，也就是赋予N0变量30%攻击，MOVR N5 1 <$STR(N0)> 指的是随机取值赋予N5，N5后面我们要用，1-N0变量之间随机取值 ，下面魔法攻击我就不一一说明了！分别是防御，魔防，魔法，道术的取值。按你自己需要进行修改!
INC N0 <$DC> <$MAXDC>
DIV N0 100
MUL N0 30
MOVR N5 1 <$STR(N0)>
INC N1 <$AC> <$MAXAC>
DIV N1 100
MUL N1 30
MOVR N6 1 <$STR(N1)>
INC N2 <$MAC> <$MAXMAC>
DIV N2 100
MUL N2 30
MOVR N7 1 <$STR(N2)>
inc N3 <$MC> <$MAXMC>
DIV N3 100
MUL N3 30
MOVR N8 1 <$STR(N3)>
inc N4 <$SC> <$MAXSC>
DIV N4 100
MUL N4 30
MOVR N9 1 <$STR(N4)>
GIVE 强化符 1 <$STR(N9)> <$STR(N8)> <$STR(N7)> <$STR(N6)> <$STR(N5)>
sendmsg 7 [提示]:恭喜{【<$USERNAME>】|253:0}玩家炼制出一张强化符!
#ELSEACT
MESSAGEBOX 您神力不足，或者您的背包内没有空白强化符!
[@强化自身]
#if
CHECKITEMW 强化符
#act
goto @强化1
#ELSEACT
MESSAGEBOX 您没有佩带强化符，请将强化符佩带至宝石位置!
break
[@强化1]
#if
#act
GETITEMADDVALUE 12 0 <$STR(M0)>
GETITEMADDVALUE 12 1 <$STR(M1)>
GETITEMADDVALUE 12 2 <$STR(M2)>
GETITEMADDVALUE 12 3 <$STR(M3)>
GETITEMADDVALUE 12 4 <$STR(M4)>
TakeEx 12
TAKE 强化符 1
ChangeHumAbility 2 + <$STR(M0)> 3600
ChangeHumAbility 4 + <$STR(M1)> 3600
ChangeHumAbility 6 + <$STR(M2)> 3600
ChangeHumAbility 8 + <$STR(M3)> 3600
ChangeHumAbility 10 + <$STR(M4)> 3600
sendmsg 7 [提示]:恭喜您1小时内防御增加<$STR(M0)>点，魔防增加<$STR(M1)>点，攻击增加<$STR(M2)>点，魔法增加<$STR(M3)>，道术增加<$STR(M4)>。
break
小手一抖，钱钱到手！